One-touch поворотники, они же Ленивые Поворотники Опции

[SSh]

Может ты просто не проткнул слой лака - не контачит вот и не показывает. Попробуй и на остальных двух точках

[lmad]

Лака там почти нет, то что было точно проткнул!

[SSh]

В таком случае сможешь или сам или кого-нибуть попросить заменить стабилизатор - LM78L05?

[Titus]

Померять питание на входе и выходе КРЕНки - на входе должно быть +12в, на выходе +5в, если на выходе пусто - КРЕНка сдохла значит, поменять ее.

[lmad]

Сам точно не смогу, мне кажется проще купить новую...

[sanche29]

Антон,давай поступим так: ты мне высылаешь свою плату,я тебе взамен новую.

[SSh]

Кстати, поднимем вопрос о креплении платы. Как видно липучка отклеивается - может все-таки лучше посадить на винты, как изначально и было задумано
(IMG:http://forum.amadeus-project.com/uploads/monthly_03_2010/post-343-1268485463.jpg)

Ну хотя-бы на один...

[Titus]

Я обычно креплю их как - слой двустороннего скотча 3М на саму плату, и слой на крышечку, потом склеиваем - получается очень плотно (IMG:style_emoticons/default/smile.gif) Для верности - разок попробовал пролить суперклеем по контуру - держится адски, при желании - отодрать потом можно (IMG:style_emoticons/default/smile.gif)
Вариант с винтами - изначально самый верный, просто, влом отверстия сверлить (IMG:style_emoticons/default/wink.gif)

[Tooth]

Собрал "ленивые поворотники" (IMG:style_emoticons/default/smile.gif) Спасибо SSh.
МК взял PIC12F629 (675 в магазинах не было). Схема из сообщения №52(без оптрона на аварийку), прошивка из №310(стр.16). Всё работает, моргает 4 раза. На дороге ещё не пробовал. Возможно 4 раза окажется лишка... Прошивку под 3 моргания для 629 в теме не нашел и исходников тоже нету:(
Уважаемый SSh, если не затруднит, сделайте пожалуйста прошивку для PIC12F629 под 3 моргания.
И ещё один вопрос: короткий моржок при включении зажигания сделан специально? и можно ли его убрать?

[SSh]

Вот исходник. Подправь переменную под свои требования.
Короткий моржок это типа как тест.

Код

'*********************************************
'* Name       : Turn_629.bas                 *
'* Author     : SSh                          *
'* MCU        : PIC12F629                    *
'* OSC        : Internal, 4MHz               *
'* Date       : 07.03.2010                   *
'* Compiler   : PicBasic Pro 2.60            *
'* Description: Turn signal one-touch system *
'*********************************************
'      +5V - 1 -|Vdd   GND|- 8  - Ground
'  RightIn - 2 -|GP5   GP0|- 7  - Rear
'   LeftIn - 3 -|GP4   GP1|- 6  - RightOut
' + 10kOhn - 4 -|MCLR  GP2|- 5  - LeftOut
'*********************************************

' Set MCU & OSC - Internal, GP4 - I/O, GP5 - I/O
@ DEVICE pic12F629, INTRC_OSC_NOCLKOUT

DEFINE OSC 4                ' Internal Freq. 4 MHz
DEFINE PULSIN_MAX 10000     ' Change up to 65535 to increase delay after touch

' Variables
Left    VAR WORD            
Right   VAR WORD            

' I/O Ports
LeftIn   var GPIO.4        
LeftOut  var GPIO.2
RightIn  Var GPIO.5
RightOut var GPIO.1
Haz      Var GPIO.0

' Constants
PulseTime con 2800          ' Delay time = 3,2s - 3...4 pulses

TRISIO = %111001            ' RA1, RA2 - Output
CMCON  = %00000111          ' Comparators - Off
GPIO = 0                    ' All ports - Low

CLEAR                       ' Clear all variables
pause 500                   ' Start-time pause

' ##################################
' ### Main part, working forewer ###
' ##################################

main:                       ' Основная программа
PULSIN RightIn, 1, Right    ' Положение рычага правого поворотника
  if Right < 8 Then         ' Если нажат
     gosub RightTurn        ' Включить правый поворотник
  Endif

PULSIN LeftIn, 1, Left      ' Положение рычага левого поворотника
  if Left < 8 Then          ' Если нажат
     gosub LeftTurn         ' Включить левый поворотник
  Endif

  If Haz = 1 then           ' Если рычаг селектора передач в положении "R"
     PAUSE 1000             ' Подождать секунду
       IF Haz = 1 THEN      ' Если все еще в этом положении
          gosub hazard      ' Включить аварийку (оба поворотника)
       ENDIF
  endif

GOTO main                     ' Возвратиться к началу программы
' ### End of main part ###

' ###################
' ### Subroutines ###        ' Подпрограммы
' ###################

RightTurn:                   ' Подпрограмма включения правого поворотника
  RightOut = 1               ' Включить поворотник
  pause PulseTime            ' Оставить его включенным на 3,2 сек.
  RightOut = 0               ' Выключить поворотник
lloop:                       ' Проверка положения рычага переключателя
PULSIN RightIn, 1, Right     ' Если рычаг все еще включен
  if Right < 8 Then          ' Ждать о тех пор,
     goto lloop              ' пока не выключится
  Endif                      ' Как только выключился
PAUSE 100                    ' Селать короткую паузу
return                       ' И вернуться в основную программу

LeftTurn:                    ' Подпрограмма включения левого поворотника
  LeftOut = 1                ' Включить поворотник
  pause PulseTime            ' Оставить его включенным на 3...4 сек.
  LeftOut = 0                ' Выключить поворотник
rloop:                       ' Проверка положения рычага переключателя
PULSIN LeftIn, 1, Left       ' Если рычаг все еще включен
  if Left < 8 Then           ' Ждать о тех пор,
     goto rloop              ' пока не выключится
  Endif                      ' Как только выключился
PAUSE 100                    ' Селать короткую паузу
return                       ' И вернуться в основную программу

hazard:                      ' Подпрограмма включения аварийки
     RightOut = 1            ' Включить одновременно правый
     LeftOut = 1             ' и левый поворотники
hloop:                       ' Проверка положения селектора передач
  if Haz = 1 then            ' Если в положении "R"
     goto hloop              ' Ждать пока не переведен
  endif                      ' в другое положение
     RightOut = 0            ' После чего выключить правый
     LeftOut = 0             ' И левый поворотники
return                       ' И вернуться в основную программу

        END ' ***** End of Program *****

[Onega]

Короткий моржок это типа как тест.

[

У меня никакого моржка нет. Разные версии?

[Tooth]

Спасибо.
Буду разбираться с компиляторами (IMG:style_emoticons/default/smile.gif)

[LLlapa]

У меня никакого моржка нет. Разные версии?

при включении зажигания еле заметно один раз аварийкой не моргает что ли?

[SSh]

Если есть проблемы - могу и скомпиллировать....

[Tooth]

Спасибо, вроде разобрался. Скомпилировал, залил прошивку, пойду проверять, считать моржки (IMG:style_emoticons/default/smile.gif)

[SSh]

Хорошо (IMG:style_emoticons/default/smile.gif) Если что не получится - пиши...

[Tooth]

Всё получилось (IMG:style_emoticons/default/smile.gif) Скомпилировал, прошил, моргает.
Правда прошилось не с первого раза, несколько раз вылезали ошибки. Помогло увеличение задержки в IC-Prog.

[SSh]

Поздравляю (IMG:style_emoticons/default/smile.gif)
Насчет задержек да, при использовании IC-Prog иногда приходится играться с ними...

[Asdwarf]

У меня детский вопрос, если можно: чем отличаются CD4001BE и CD4001AE.
AE в городе не нашел, есть ВЕ за недорого и К561ЛЕ5 (отечественные) по 80р.
Чего брать-то? (IMG:style_emoticons/default/huh.gif)

[SSh]

Функционально - ничем. Ставь любую из трех.